# Whether the given 4-digit year is a leap year.
#
sub leap_year_p {
  my ($year) = @_;
  return ((($year % 4 == 0) &&     # divisible by 4
           (($year % 100) ||       # ...unless divisble by 100
            ($year % 400 == 0)))   # ...and not divisible by 400
          ? 1 : 0);
}

# Returns the number of days in the given month, considering leap years.
#
my @days_per_month = (31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31);
sub days_per_month {
  my ($month, $year) = @_;
  my $days = $days_per_month[$month-1];
  $days++ if ($month == 2 && leap_year_p($year));  # feb leapday
  return $days;
}

And this calculation is kinda crazy too:

# Given a date, returns the day of the week on which it falls (0-6, sun-sat)
#
sub dotw {
  my ($dotm, $month, $year) = @_;

  # From the sci.math FAQ:
  #
  #  The following formula, which is for the Gregorian calendar only, may be
  #  more convenient for computer programming.  Note that in some programming
  #  languages the remainder operation can yield a negative result if given
  #  a negative operand, so "mod 7" may not translate to a simple remainder.
  #
  #      W == (k + [2.6m - 0.2] - 2C + Y + [Y/4] + [C/4]) mod 7
  #         where [] denotes the integer floor function (round down),
  #         k is day (1 to 31)
  #         m is month (1 = March, ..., 10 = December, 11 = Jan, 12 = Feb)
  #                       Treat Jan & Feb as months of the preceding year
  #         C is century (1987 has C = 19)
  #         Y is year    (1987 has Y = 87 except Y = 86 for Jan & Feb)
  #         W is week day (0 = Sunday, ..., 6 = Saturday)
  #
  #  Here the century & 400 year corrections are built into the formula.
  #  The [2.6m-0.2] term relates to the repetitive pattern that the 30-day
  #  months show when March is taken as the first month.

  my $k = $dotm;
  my $m = 1 + (($month + 9) % 12);    # (1-12) => (11, 12, 1-10)
  my $y = $year - ($m >= 11 ? 1 : 0); # subtract a year for jan/feb
  my $C = int ($y/100);
  my $Y = int ($y%100);
  my $W = (($k +
            int ((2.6 * $m) - 0.2)
            - (2 * $C)
            + $Y
            + int ($Y / 4)
            + int ($C / 4)
            + 7)
           % 7);
  return $W;
}

I was a few months too late… (May 2000, according to my userinfo page.)